--file to verify in Macaulay2 (http://www.math.uiuc.edu/Macaulay2/) 
--computation in Theorem 1.17 and Appendix, 
--C. Hillar L.H. Lim, Most tensor problems are NP-hard, JACM, 2013.

R = QQ[a_1,a_2,a_3,b_1,b_2,b_3,c_1,c_2,c_3,d_1,d_2,d_3]

F1 = a_1*a_2*a_3+c_1*c_2*c_3-2
F2 = a_1*a_3*b_2+c_1*c_3*d_2
F3 = a_2*a_3*b_1+c_2*c_3*d_1
F4 = a_3*b_1*b_2+c_3*d_1*d_2+4
F5 = a_1*a_2*b_3+c_1*c_2*d_3
F6 = a_1*b_2*b_3+c_1*d_2*d_3+4 
F7 = a_2*b_1*b_3+c_2*d_1*d_3-4 
F8 = b_1*b_2*b_3+d_1*d_2*d_3

I = ideal(F1,F2,F3,F4,F5,F6,F7,F8)

g = 2*c_2^2 - d_2^2
h = c_1*d_2*d_3 + 2

--Should both be zero thus in the ideal
g % I
h % I

--we will now show how to express g = 2*c_2^2 - d_2^2 and 
--h = c_1*d_2*d_3 + 2  as a rational integer polynomial linear combination of 
--polynomials in F.  Thus g,h are consequences of F.

G1 = -1/8*b_1*b_2*b_3*c_2*d_2+1/8*a_2*b_1*b_3*d_2^2
G2 = 1/8*b_1*b_2*b_3*c_2^2-1/8*a_2*b_1*b_3*c_2*d_2
G3 = -1/2*c_2*d_2
G4 = 1/2*c_2^2
G5 = 1/8*a_3*b_1*b_2*c_2*d_2-1/8*a_2*a_3*b_1*d_2^2
G6 = -1/8*a_3*b_1*b_2*c_2^2+1/8*a_2*a_3*b_1*c_2*d_2
G7 = 1/4*d_2^2
G8 = -1/4*c_2*d_2

--should show up as 2*c_2^2 - d_2^2
F1*G1 + F2*G2 + F3*G3 + F4*G4 + F5*G5 + F6*G6 + F7*G7 + F8*G8

H1 = 0 
H2 = (1/32)*b_1*b_2*b_3*c_2*d_1*d_3-(1/32)*a_2*b_1*b_3*d_1*d_2*d_3 
H3 = -(1/32)*b_1*b_2*b_3*c_1*d_2*d_3+(1/32)*a_1*b_2*b_3*d_1*d_2*d_3 
H4 = -(1/32)*a_1*b_2*b_3*c_2*d_1*d_3+(1/32)*a_2*b_1*b_3*c_1*d_2*d_3 
H5 = -(1/8)*b_1*b_2*b_3 
H6 = 1/2 
H7 = (1/8)*a_1*b_2*b_3-(1/8)*c_1*d_2*d_3 
H8 = (1/8)*c_1*c_2*d_3

--should show up as h = c_1*d_2*d_3 + 2
F1*H1 + F2*H2 + F3*H3 + F4*H4 + F5*H5 + F6*H6 + F7*H7 + F8*H8